How can I set an edit control to be Latin-only? Topic is solved

[william_ahk]

When an input method is on one would have to switch it off to enter latin letters directly, is there any way to make an edit control declare that it only accepts latin letters, temporarily switch to English input, and switch back after losing focus?

[mikeyww]

One workaround could be to set temporary hotkeys that ignore characters that should not appear.

[tmplinshi]

Code: Select all

DisableControlIME(hWnd, bDisable := true) {
	flag := bDisable ? 0x0020 ; IACE_IGNORENOCONTEXT
	                 : 0x0010 ; IACE_DEFAULT
	DllCall("Imm32\ImmAssociateContextEx", "ptr", hWnd, "ptr", 0, "uint", flag)
}

; Example
Gui, Add, Edit, xm w300 +HwndhEdit, 
Gui, Add, Checkbox, x+10 hp vcb2 gDisableIME, Disable IME
Gui, Add, Edit, xm w300, 
Gui, Show
Return

DisableIME:
	GuiControlGet, b,, % A_GuiControl
	DisableControlIME(hEdit, b)
Return

GuiClose:
ExitApp

[mikeyww]

That looks cool. Does that DLL call disable the non-Latin input? How does it do that?

[william_ahk]

@tmplinshi This is really gool (good&cool)! Thank you so much