VBA: Text nach unten schieben

[Rohwedder]

Hallo,
erster Versuch mit VBA unter Autohotkey:

Code: Select all

#IfWinActive ahk_class OpusApp
q::
Word := ComObjActive("Word.Application")
If !Word
{
	MsgBox, Word ist leer
	Return
}
ToolTip,% Word.ActiveDocument.FullName  
Sleep, 1000
ToolTip
;https://msdn.microsoft.com/de-de/vba/word-vba/articles/font-position-property-word
;der markierte Text wird um 2 Punkt nach unten verschoben.
Word.Selection.Font.Position := -2
Return

Das aktive Dokument wird erkannt, aber der selektierte Text leider nicht abgesenkt!
Muß man irgendwie noch befehlen, daß das gewünschte auch passieren soll?
(Windows 7, Word 2010, Autohotkey Admin, UAC tot.)

[LuckyJoe]

... also bei mir funktioniert dein Script einwandfrei mit Word 2003.

[Rohwedder]

Hallo,
bei mir heute zunächst auch (gestern nie!).
Dann häufte sich der Fehler:
Error: 0x800401E3 - Vorgang nicht verfügbar.
---> 003: Word := ComObjActive("Word.Application")
und nachdem ich dies mit Try versehen hatte, dann:
Error: 0x800706BA - Der RPC-Server ist nicht verfügbar.
Specifically: Selection
---> 017: Word.Selection.Font.Position := -2
Also noch ein Try und es läuft jetzt halbwegs.
Irgendetwas am Skript ist faul, denn so unzuverlässig kann doch VBA nicht sein!

[just me]

Moin,

auch wenn das kleinlich klingen mag, mit VB(A) hat das wenig zu tun. Hier geht es um die in AHK eingebaute Unterstützung von COM Objekten. Die VB(A) Syntax liefert aber gute Hinweise darauf, wie man die Objekte in AHK ansprechen kann.

[LuckyJoe]

Hi,

vielleicht helfen folgende Ansätze: ComObjError(), VarSetCapacity()...
Ggf. muss man den Speicher wieder freigeben (word := "")?

Viel Erfolg!
Lucky Joe

[nnnik]

Wenn so ein Fehler auftaucht bedeutet das, dass diese Aktion fehlgeschlagen ist.
Bei dir ist das ganze wie eine lange Reihe Dominosteine aufgebaut und da der erste nicht fällt klappen die anderen auch nicht um.

Was fehlschlägt ist das erhalten des aktiven Word Programms. Das kann daher kommen, dass Word nun als Admin ausgeführt wird, oder einfach schlichtweg nicht läuft.

[Rohwedder]

Hallo,
vielen Dank für die Hilfen.
Dies hier ist letztendlich daraus geworden:

Code: Select all

#IfWinActive ahk_class OpusApp ;Word
+WheelUp:: ;Markierung absenken/anheben
+WheelDown::
Try
	Word := ComObjActive("Word.Application")
IF !Word
	Return
FontPosition := Word.Selection.Font.Position
IF FontPosition > 100000 ;Markierung enthält unterschiedliche FontPositionen
	FontPosition := 0, FoPoDel := 0
Else IF A_ThisHotkey = +WheelUp
	FoPoDel := !FoPoDel Or Abs(FontPosition) < 5 ? 1 : Max(1,++FoPoDel)
Else If A_ThisHotkey = +WheelDown
	FoPoDel := !FoPoDel Or Abs(FontPosition) < 5 ? -1 : Min(-1,--FoPoDel)
Else
	Return
ToolTip,% Word.Selection.Font.Position := FontPosition += FoPoDel
SetTimer, ToolTipWeg, -1000
Return
ToolTipWeg:
FoPoDel := 0, Word := ""
ToolTip
Return

Wenn Text mit Grafik in einer Textzeile stehen, kann ich sie jetzt bequem vertikal justieren.