shell.exec verstecken

[LuckyJoe]

Hallo zusammen,

ich bastel gerade an einem Script, mit dem ich die Metadaten aus einer PDF-Datei auslesen möchte. Dazu verwende ich das externe Tool "ExifTool". Das klappt auch schon ganz gut:

Code: Select all

#NoEnv
#SingleInstance force

ExifTool  = "c:\Program Files (x86)\!Grafik\ExifTool\exiftool.exe"
PDFCD     = -createdate
PDFMD     = -modifydate
FileCD    = -filecreatedate
FileMD    = -filemodifydate
MyTest    = -s -createdate -modifydate -filecreatedate -filemodifydate
PDFDatei   = "d:\xxx\Test3.pdf"

ProgrammMitParameter = % ExifTool " " MyTest " " PDFDatei

shell := ComObjCreate("WScript.Shell")
exec := shell.exec(ProgrammMitParameter)
Ergebnis := exec.StdOut.ReadAll()
MsgBox, % Ergebnis

... allerdings stört mich, dass das Shell-Fenster kurz aufflackert. Wie kann ich das unterdrücken?
Danke im Voraus für eure Hilfe

HG - Lucky Joe

[swagfag]

Code: Select all

#NoEnv
#SingleInstance Force

ExifTool  = "c:\Program Files (x86)\!Grafik\ExifTool\exiftool.exe"
PDFCD     = -createdate
PDFMD     = -modifydate
FileCD    = -filecreatedate
FileMD    = -filemodifydate
MyTest    = -s -createdate -modifydate -filecreatedate -filemodifydate
PDFDatei   = "d:\xxx\Test3.pdf"

ProgrammMitParameter := Format("cmd /c ""{} {}"" ""{}"" | clip", ExifTool, MyTest, PDFDatei) ; /C run->exit

shell := ComObjCreate("WScript.Shell")

clipSaved := ClipboardAll
Clipboard := ""

shell.Run(ProgrammMitParameter, 0, true) ; hidden, synchronous
ClipWait 1
Ergebnis := Clipboard
Clipboard := clipSaved

MsgBox, % Ergebnis

[LuckyJoe]

Hi swagfag,

Danke ersteinmal für deine Unterstützung; das CMD-Fenster poppt zwar nicht auf, ich bekomme aber nur eine leere Msgbox.

HG - Lucky Joe

[swagfag]

try this one. note the use of := (expressions) instead of = (traditional)

Code: Select all

exiftool := "D:\Downloads\exiftool-11.20\exiftool.exe"
args := "-s -createdate -modifydate -filecreatedate -filemodifydate"
pdf := "D:\Downloads\exiftool-11.20\test.pdf"

shell := ComObjCreate("WScript.Shell")

clipSaved := ClipboardAll
Clipboard := ""

SplitPath exiftool, exe, dir
cmd := Format("cmd /c cd /d ""{}"" & ""{}"" {} ""{}"" | clip", dir, exe, args, pdf)
shell.Run(cmd, 0, true) ; hidden, synchronous

ClipWait 1
Ergebnis := Clipboard
Clipboard := clipSaved

MsgBox, % Ergebnis

[LuckyJoe]

... yeah! ... That works fine - thanky you!