Daten in ListView laden Topic is solved

[KHA]

Hi,
Wie kann ich die Daten in eine Listview nebeneinander laden.
Ich habe es paar mal versucht, bekomme es nicht hin.
Die Liste wird mehrmals untereinander geladen.
LG

Code: Select all

frob=
(
Rot:Tomaten
Gelb:Bananen
Grün:Grünkohl
Braun:Kokosnuss
)

Gui, Add, ListView, W700 Grid, Farbe|Obst
Gui, Add, Button, Gload, Load
Gui, Show
return

load:

Loop, parse, frob, `r`n
{

	Loop, parse, A_loopfield, `:
	{
	LV_Add("",A_LoopField,A_LoopField)
	}


/*1. Versuch

frbost := StrSplit(A_Loopfield, ":")
LV_Add("", frbost[A_Index], frbost[A_Index]+)
*/
}

return
GuiClose:
ExitApp

[wolf_II]

Versuch mal:

Code: Select all

frob=
(
Rot:Tomaten
Gelb:Bananen
Grün:Grünkohl
Braun:Kokosnuss
)

Gui, Add, ListView, W700 Grid, Farbe|Obst
Gui, Add, Button, Gload, Load
Gui, Show
return

load:
Loop, parse, frob, `n, `r
{
	split := StrSplit(A_loopfield, ":")
	LV_Add("", split[1], split[2])
}
return

GuiClose:
ExitApp

Ich hoffe das hilft.

[KHA]

vielen Dank!

manchmal sieht man vor lauter Bäumen den Wald kaum.

[just me]

Moin,

aus der Kiste 'Kleine Tipps und Tricks':

LV_Add() ist eine Funktion mit einer variablen Anzahl von Parametern, die man als variadische Funktion behandeln kann. Wenn alle Felder einer Listenzeile in das ListView-Control gestellt werden sollen und man das Feldarray mit einem StrSplit() Aufruf erzeugt, kann man das deshalb auch mit einem variadischen Funktionsaufruf machen:

Code: Select all

Loop, Parse, frob, `n, `r
   LV_Add("", StrSplit(A_LoopField, ":")*)

[KHA]

Danke für den Super Tipp