Tested on the current version 3.23.1
Currently:
- auto walk
- auto run
- look around while away
- auto scan
- help reposition fullscreen-windowed mode.
- Beep on screenshot
Let me know of other ideas.
Matthew
Im
Code: Select all
#Requires AutoHotkey v2.0
#SingleInstance Force
DetectHiddenWindows 1
if not A_IsAdmin
Run '*RunAs "' A_ScriptFullPath '"'
;For StarCitizen
; tested in:
; - 3.23.1
; - 3.23.0
; - 3.22.1
;
; Commands only run in the SC window.
; single beep when command starts, double beep when command ends
_starCitizenAppTitle := "Star Citizen"
;Only for StarCitizen
#HotIf WinActive(_starCitizenAppTitle)
; Auto walk
;
; auto walk forward (alt+w)
; (also moves ship)
;
!w Up:: {
SingleBeep(1050)
loop {
Send("{w down}")
} until KeyWait("w", "DT0.1")
Send("{w up}")
DoubleBeep(1050)
}
; Auto run
;
; Auto run forward (shift+alt+w)
; (Works with ship, but uses boost)
;
+!w Up:: {
SingleBeep(1050)
loop {
Send("{w down}")
Send("{LShift down}")
} until KeyWait("w", "DT0.1")
Send("{w up}")
Send("{LShift up}")
DoubleBeep(1050)
}
; Random looking
;
; Pretend to be looking around while walking or flying
; Will only work while SC has focus. You may have to reset the view afterwards
!f4 up:: {
SingleBeep(2000)
Send("{f4}")
Loop {
Send("{z down}")
Sleep 50
mousemove( Random(1, 100), Random(1, 100), Random(50, 100), "R")
Sleep 50
Send("{z up}")
if( KeyWait( "f4", "DT10" ) ) {
;if( KeyWait( "f4", "DT" . String( Random(30, 300) ) ) ) {
Break
}
SoundBeep(2000,50)
}
}
; Auto scan
;
; ping every two seconds
; double tap Tab to start, Tab again to stop.
~Tab Up:: {
if( KeyWait( "Tab", "DT.3" ) ) {
KeyWait( "Tab", "T.3" )
SingleBeep(1900)
Loop {
Send("{Tab}")
if( KeyWait( "Tab", "DT2" ) ) {
Break
}
}
DoubleBeep(1900)
}
}
; Reposition window
;
; move the fullscreen-but-windowed window up to hide the title bar
; Alt + M
!m:: {
WinGetPos( , , , &_windowHeight, _starCitizenAppTitle )
WinMove( , Min(A_ScreenHeight-_windowHeight, 0) ,,, _starCitizenAppTitle )
}
; move it back down
; Shift + Alt + M
+!m:: {
WinMove( , 0, , , _starCitizenAppTitle )
}
; A little bit of feedback on screenshot button
~PrintScreen Up:: {
; todo, pop up most recent screenshot
DoubleBeep(2000)
}
~!b::DoubleBeep(700) ;)
SingleBeep(b) {
SoundBeep(b,75)
}
DoubleBeep(b) {
SoundBeep(b,75)
SoundBeep(b,100)
}