How to detect that mouse cursor leaves script's gui?

[Zvonko]

What would be the simplest way to detect that the mouse cursor is moved outside the script's gui (without calculating coordinates etc.)?

Edited: I forgot to mention that in my script I already use OnMouseMove for other purpose, so I prefer a solution which works inside OnMouseMove.

Code: Select all

Gui Test: +HwndIdTest -dpiScale
Gui Test: Show, x50 y50 w800 h500

OnMessage(0x200, "OnMouseMove")
 
Return

OnMouseMove()
{
   Global IdTest
   MouseGetPos mx, my, IdWindow
   WinGetTitle, WinT, ahk_id %IdWindow%
   ToolTip The cursor is in window %WinT%, 150, 3
   If (IdWindow != IdTest)					; Doesn't work,
      MsgBox Out! Now in %WinT%!			; of course.
}
 
TestGuiClose:
ExitApp
 

[Gicu]

with a timer seems to work

Code: Select all

Gui Test: +HwndIdTest -dpiScale
Gui Test: Show, x50 y50 w800 h500
 
SetTimer, onout
Return

onout:

   MouseGetPos mx, my, IdWindow
   WinGetTitle, WinT, ahk_id %IdWindow%
   ToolTip The cursor is in window %WinT%, 150, 3
   If (IdWindow <> IdTest)
      ToolTip Out! Now in %WinT%!
      
Return 
Return

[Zvonko]

Thank you very much, Gicu.
I forgot to mention that in my script I already use OnMouseMove for other purpose, so I prefer a solution which works inside OnMouseMove.

[punchin]

You're already getting the mouse position, so just add in to OnMouseMove the calculation to test of its outside the gui. There is no simpler way than that that I know of. That really simple, especially if you use the built in variables A_GuiX, A_GuiY, A_GuiWidth, and A_GuiHeight.

[just me]

Posted to a window when the cursor moves. If the mouse is not captured, the message is posted to the window that contains the cursor. Otherwise, the message is posted to the window that has captured the mouse.

Source

In other words, if your Gui didn't capture the mouse and the cursor is outside your Gui you won't receive WM_MOUSEMOVE messages.

[punchin]

If OnMouse move is not being called by the gui at times, you will need to set a timer to fire it manually.

[noname]

You can use the parameters " OnMouseLeave " message to detect it.

Code: Select all

Gui Test: +HwndIdTest -dpiScale
Gui Test: Show, x50 y50 w800 h500

VarSetCapacity(tme,16,0)

NumPut(16,tme,0), NumPut(2,tme,4), NumPut(IdTest,tme,8)
OnMessage(0x200, "OnMouseMove")
OnMessage(0x2A3,"OnMouseLeave")

Return

OnMouseMove( wParam, lParam, Msg,hwnd ) {
global tme
DllCall( "TrackMouseEvent","uint",&tme )
    x := lParam & 0xFFFF
    y := lParam >> 16
tooltip Over window x=%x%  y=%y%
}

OnMouseLeave(){
tooltip leaving window
}

 
TestGuiClose:
ExitApp

[Zvonko]

Thank you very much, Gicu, punchin, just me, noname!

Conclusion:
There really seems to be no simple AHK method (usable inside OnMouseMove) to detect that the mouse cursor leaves script's window! That's amazing, isn't it?

So I was forced to give up the OnMouseMove method and to use a timer...

[bbscrip]

This topic is a few years ago, but I did not find solution simple enough on same subject. I edited above example with small loop to track title and check for a change.

Code: Select all

Gui Test: +HwndIdTest -dpiScale
Gui Test: Show, x50 y50 w800 h500

OnMessage(0x200, "OnMouseMove")
 
Return

OnMouseMove()
{
   MouseGetPos mx, my, IdWindow
   WinGetTitle, WinT, ahk_id %IdWindow%
   Title_buffer := WinT
   ToolTip The cursor is in window %WinT%, 150, 3
   Loop, 
    {
      MouseGetPos mx, my, IdWindow  
	  WinGetTitle, WinT, ahk_id %IdWindow%
	 	  if !("" . Title_buffer = "" . WinT)
	     {
            MsgBox, The cursor is now out of %Title_buffer% GUI! 
			break
		 }
	  Sleep, 200
	}
}
 
TestGuiClose:
ExitApp

Works fine for me.

[xan2622]

This topic is a few years ago, but I did not find solution simple enough on same subject. I edited above example with small loop to track title and check for a change.

Code: Select all

Gui Test: +HwndIdTest -dpiScale
Gui Test: Show, x50 y50 w800 h500

OnMessage(0x200, "OnMouseMove")
 
Return

OnMouseMove()
{
   MouseGetPos mx, my, IdWindow
   WinGetTitle, WinT, ahk_id %IdWindow%
   Title_buffer := WinT
   ToolTip The cursor is in window %WinT%, 150, 3
   Loop, 
    {
      MouseGetPos mx, my, IdWindow  
	  WinGetTitle, WinT, ahk_id %IdWindow%
	 	  if !("" . Title_buffer = "" . WinT)
	     {
            MsgBox, The cursor is now out of %Title_buffer% GUI! 
			break
		 }
	  Sleep, 200
	}
}
 
TestGuiClose:
ExitApp

Works fine for me.

Hi bbscrip.
Would you happen to have a AHK v2 version of this script ?