MouseMover: Pixel-Perfect Pointer Precision!

[Hactar]

IMPORTANT: Since Win10, BlockInput MouseMove (which this program requires for it's core feature) no longer works! Hopefully this will be fixed in a soon AHK version, but until then this program doesn't freeze your mouse. (It can still move it by one pixel at a time.) Apparently that problem went away on it's own. Never mind then...

Maybe I'm the only crazy person out there who likes pixel-perfect pointer positioning precision. XD

HOW TO USE:
• Press [Ctrl] + [Win] + [M] (or any other hotkey you choose) to freeze/unfreeze your mouse.
• While it is frozen, you can use WASD or the arrow keys to move it by one pixel at a time.
• Hold down [Ctrl] to move your mouse by ten pixels at a time
• Hold down [Shift] to move it by 100 pixels at a time.

That's really all there is too it...

MouseMover.ahk (#Include after auto-execute section if used with another script)

Code: Select all

#MaxHotkeysPerInterval 200		; Allows for rapid fire hotkeys (recommended, but not required)

^#m::
	Suspend On
	If ( MouseMover := !MouseMover ) {
		BlockInput MouseMove
		SoundBeep, 523.251, 100
		SoundBeep, 783.991, 100
	} Else {
		BlockInput MouseMoveOff
		SoundBeep, 783.991, 100
		SoundBeep, 523.251, 100
	}
	Suspend Off
Return

#If MouseMover

	w::
	Up::MouseMove 0, -1, , R
	s::
	Down::MouseMove 0, 1, , R
	a::
	Left::MouseMove -1, 0, , R
	d::
	Right::MouseMove 1, 0, , R
	
	^w::
	^Up::MouseMove 0, -10, , R
	^s::
	^Down::MouseMove 0, 10, , R
	^a::
	^Left::MouseMove -10, 0, , R
	^d::
	^Right::MouseMove 10, 0, , R
	
	+w::
	+Up::MouseMove 0, -100, , R
	+s::
	+Down::MouseMove 0, 100, , R
	+a::
	+Left::MouseMove -100, 0, , R
	+d::
	+Right::MouseMove 100, 0, , R
	
#If

Oh, and it makes funny beeping noises too!

[ozzii]

Cool.
If I may a suggestion:
Have the position of the mouse in a tooltip.
And maybe also the color under the mouse.

[WAZAAAAA]

Pretty cool, thanks for the script, I've used it.

But why did you write these:
SoundBeep, 523.251, 100
SoundBeep, 783.991, 100

instead of just these?
SoundBeep, 523, 100
SoundBeep, 783, 100

And what about that lonely #If in the end? lol

[boiler]

The lonely #If is there so that his earlier #If condition won't apply to any other hotkey definitions that might be added after it. Even though he doesn't have any more currently, it's good practice to do that so he doesn't have to remember later if he does add some.

[JJohnston2]

Those particular frequencies are musical notes... C & G... probably copy/pasted somewhere else vs. coded from scratch.

[Hactar]

But why did you write these:
SoundBeep, 523.251, 100
SoundBeep, 783.991, 100

instead of just these?
SoundBeep, 523, 100
SoundBeep, 783, 100

Those particular frequencies are musical notes... C & G... probably copy/pasted somewhere else vs. coded from scratch.

Yes, I just copy-pasted the notes from Wikipedia and didn't know why I should bother truncating them. AutoHotkey does take decimal input for those, even if it makes very little or no difference in the sound that comes out. I'm not really sure why I left three decimals in there...

[kunkel321]

Pretty cool idea! I didn't even know I needed this until you posted it!