Hash from string, hex or file, HMAC, Salt

[jNizM]

SHA-3 (Keccak) Calculator

[jNizM]

CRC32 (Cyclic redundancy check)

---

Implementation

Code: Select all

CRC32(str)
{
    static table := []
    loop 256 {
        crc := A_Index - 1
        loop 8
            crc := (crc & 1) ? (crc >> 1) ^ 0xEDB88320 : (crc >> 1)
        table[A_Index - 1] := crc
    }
    crc := ~0
    loop, parse, str
        crc := table[(crc & 0xFF) ^ Asc(A_LoopField)] ^ (crc >> 8)
    return Format("0x{:x}", ~crc)
}

example:

Code: Select all

MsgBox % CRC32("The quick brown fox jumps over the lazy dog")

output:

Code: Select all

0x414fa339

---

DllCall / WinAPI

Code: Select all

CRC32(str, enc = "UTF-8")
{
    l := (enc = "CP1200" || enc = "UTF-16") ? 2 : 1, s := (StrPut(str, enc) - 1) * l
    VarSetCapacity(b, s, 0) && StrPut(str, &b, floor(s / l), enc)
    CRC32 := DllCall("ntdll.dll\RtlComputeCrc32", "UInt", 0, "Ptr", &b, "UInt", s)
    return Format("0x{:x}", CRC32)
}

example:

Code: Select all

MsgBox % CRC32("The quick brown fox jumps over the lazy dog")

output:

Code: Select all

0x414fa339

[jNizM]

Custom hashing algorithm's

---

RSHash (Robert Sedgewick's string hashing algorithm)

Implementation

Code: Select all

RSHash(str)
{
    a := 0xF8C9, b := 0x5C6B7, h := 0
    loop, parse, str
        h := h * a + Asc(A_LoopField), a *= b
    return (h & 0x7FFFFFFF)
}

example & output

Code: Select all

MsgBox % RSHash("jdfgsdhfsdfsd 6445dsfsd7fg/*/+bfjsdgf%$^") ; <== 2012450421

---

JSHash (A bitwise hash function written by Justin Sobel)

Implementation

Code: Select all

JSHash(str)
{
    h := 0x4E67C6A7
    loop, parse, str
        h ^= ((h << 5) + Asc(A_LoopField) + (h >> 2))
    return (h & 0x7FFFFFFF)
}

example & output

Code: Select all

MsgBox % JSHash("jdfgsdhfsdfsd 6445dsfsd7fg/*/+bfjsdgf%$^") ; <== 1103173151

[JoeWinograd]

Hi jNizM,
First, thank you for posting this — great stuff!

My script encrypts a string with a call to your SHA512 function, which works fine. Later on in the script, I want to decrypt the encrypted string, but I don't see a function to do that. Is there one? Thanks, Joe

[jNizM]

Hashing != En-/Decryption

Hash function
Cryptographic hash function
vs
Encryption

[JoeWinograd]

Hashing != En-/Decryption

Yes, thank you! Brain cramp on my part. Sorry about that. Regards, Joe

[jNizM]

New updates will be shared here => CNG (Cryptography API: Next Generation)