UrlDownloadToFile

Downloads a file from the Internet.

UrlDownloadToFile, URL, Filename

Parameters

URL

URL of the file to download. For example, https://someorg.org might retrieve the welcome page for that organization.

Filename

Specify the name of the file to be created locally, which is assumed to be in %A_WorkingDir% if an absolute path isn't specified. Any existing file will be overwritten by the new file.

This command downloads to a file. To download to a variable instead, see the example below.

Error Handling

[v1.1.04+]: This command is able to throw an exception on failure. For more information, see Runtime Errors.

ErrorLevel is set to 1 if there was a problem or 0 otherwise.

Remarks

The download might appear to succeed even when the remote file doesn't exist. This is because many web servers send an error page instead of the missing file. This error page is what will be saved in place of Filename.

Internet Explorer 3 or greater must be installed for this command to work. Firewalls or the presence of multiple network adapters may cause this command to fail. Also, some websites may block such downloads.

Caching:

Proxies: UrlDownloadToFile will use a proxy server to access the Internet if such a proxy has been configured in Microsoft Internet Explorer's settings.

FTP and Gopher: [v1.0.48.04+] supports FTP and Gopher URLs. For example:

UrlDownloadToFile, ftp://example.com/home/My File.zip, C:\My Folder\My File.zip  ; Log in anonymously.
UrlDownloadToFile, ftp://user:[email protected]:21/home/My File.zip, C:\My Folder\My File.zip  ; Log in as a specific user.
UrlDownloadToFile, ftp://user:[email protected]/My Directory, C:\Dir Listing.html  ; Gets a directory listing in HTML format.

FileRead, FileCopy

Examples

Downloads a text file.

UrlDownloadToFile, https://www.autohotkey.com/download/1.1/version.txt, C:\AutoHotkey Latest Version.txt

Downloads a zip file.

UrlDownloadToFile, https://someorg.org/archive.zip, C:\SomeOrg's Archive.zip

Downloads text to a variable.

whr := ComObjCreate("WinHttp.WinHttpRequest.5.1")
whr.Open("GET", "https://www.autohotkey.com/download/1.1/version.txt", true)
whr.Send()
; Using 'true' above and the call below allows the script to remain responsive.
whr.WaitForResponse()
version := whr.ResponseText
MsgBox % version

Makes an asynchronous HTTP request.

req := ComObjCreate("Msxml2.XMLHTTP")
; Open a request with async enabled.
req.open("GET", "https://www.autohotkey.com/download/1.1/version.txt", true)
; Set our callback function, requires [v1.1.17+].
req.onreadystatechange := Func("Ready")
; Send the request.  Ready() will be called when it's complete.
req.send()
/*
; If you're going to wait, there's no need for onreadystatechange.
; Setting async=true and waiting like this allows the script to remain
; responsive while the download is taking place, whereas async=false
; will make the script unresponsive.
while req.readyState != 4
    sleep 100
*/
#Persistent

Ready() {
    global req
    if (req.readyState != 4)  ; Not done yet.
        return
    if (req.status == 200) ; OK.
        MsgBox % "Latest AutoHotkey version: " req.responseText
    else
        MsgBox 16,, % "Status " req.status
    ExitApp
}