Небольшой вопросик в коде

[Vladik2304]

RegexMatch(A_LoopField,

[mcl]

Подскажите, почему этот код находит id через раз. Т.е. он не всегда находит число в [ ]
Ниже прикрепил скрин из чата и код

[Vladik2304]

Подскажите, почему этот код находит id через раз. Т.е. он не всегда находит число в [ ]
Ниже прикрепил скрин из чата и код

Предоставил чатлог файлом ниже.
Отвечу сразу на вопрос: "Что будет делать код если не будет найден id", надо чтобы просто через AddChatMessage вывод "id не найден"

[mcl]

Code: Select all

FileRead, Str, chatlog.txt

rx =                  ; Регулярное выражение разбито на части для упрощения понимания
( Join LTrim Comments
  m)                  ; Флаг m (multi-line) упрощает работу с многострочными текстами
  ^                   ; Символ ^ - начало строки (с флагом m - любой строки, а не всего текста)
  \[\d\d:\d\d:\d\d\]  ; Метка времени в формате [NN:NN:NN], где N - любое число
  \s*                 ; Пробелы после метки времени (похоже, обычно один, но мало ли что)
  \S+_\S+             ; Имя в формате ТЕКСТ_ТЕКСТ; \S - не-пробелы (например, буквы)
  \[(\d+)\]           ; Числовой Id в квадратных скобках. Круглые скобки - для записи в match1
  \s:\s               ; Пробел-двоеточие-пробел, разделяющие автора сообщения и его текст
  .*                  ; Текст сообщения, совершенно любой.
  $                   ; Конец строки (как и ^, зависит от флага m)
)

RegexMatch(Str, rx, match)

If (match1 == "") {
	MsgBox ID не найден   ; AddChatMessage("ID не найден")
	Return
}

MsgBox % match1
; остальной код

Подсветка кода тут несколько страдает, но на работоспособность это влиять не должно.
Флаг m позволяет избавиться от команд StringReplace и возни с переносами строк (`n)

Если этот скрипт запустить в той же папке, что и chatlog.txt, он выдаёт id из сообщения первого найденного игрока. Но есть важные моменты:

1. Выдаётся id простого игрока, не администратора. В сообщениях администраторов между меткой времени и именем стоит статус ([00:00:00] Администратор Иван_Иванов[1]), а по регулярке после метки времени сразу должно идти имя.

2. Выдаётся id только для публичных сообщений. Например, Петр_Петров[2] для Семен_Семенов[3] будет пропущено, так как по регулярке после имени и id должно сразу идти двоеточие и текст сообщения.

3. Текст сообщения может быть любым. В вашем исходном коде в тексте сообщения должна была быть хотя бы одна цифра − не знаю, зачем.

Соответственно, для достижения желаемого результата, вероятно, придётся подправить те или иные части регулярки.