4 options to change the current folder in Windows Explorer

Get help with using AutoHotkey and its commands and hotkeys
User avatar
JnLlnd
Posts: 272
Joined: 29 Sep 2013, 21:29
GitHub: JnLlnd
Location: Montreal, Quebec, Canada
Contact:

4 options to change the current folder in Windows Explorer

04 Nov 2013, 23:49

Can I ask for your help? Working on a AHK project where I need to change the current folder in Windows Explorer, I found various methods to achieve this.

Some of them were not working on my system. For one, I found that the language version of my Windows 7 was in cause. Namely, the Alt-D shortcut to focus on the address bar in Windows Explorer is known to be buggy in French locale.

With the help of chaz and using a script from rbrtryn on the old forum, I scripted various approaches to change the folder. One of them (from rbtryn) was coded specifically for WinXP (but, on my XP system, all methods work equally well).

You will find it in the script below with some debugging code. If you have 5 minutes, could you run this piece of code and paste the resulting log file (5 lines) in this thread? This will help identify the most reliable options. Special request to users of other language versions than English: you can help find if other locale has problem with the Alt-D shortcut.

Thanks!

Code: Select all

#NoEnv
#SingleInstance force

Global strEnv := A_AhkVersion . " | " . A_OSVersion . " | " . A_Is64bitOS . " | " . A_Language
Global strLog := "Test_Name | Test_Result | A_AhkVersion | A_OSVersion | A_Is64bitOS | A_Language`r`n"
StringReplace, strLogFile, A_ScriptName, .ahk
strLogFile := A_Temp . "\" . strLogFile . ".log"

Info("The script will open ""Windows Explorer"".")
run, Explorer
Info("The script will now perform the same task (changing folders in Explorer) using 4 different methods.")

if (A_OSVersion = "WIN_XP")
{
	; WinXP ControlSend Method
	strFolder := "C:\Windows"
	Info("Method 1)`nIn the next step, the folder in Explorer should change to your """ . strFolder . """ folder.")
	if not ControlEdit1Exist()
	{
		PostMessage, 0x111, 41477, 0, , A ; Show Address Bar
		while not ControlEdit1Exist()
			Sleep 0
		PostMessage, 0x111, 41477, 0, , A ; Hide Address Bar
	}
	ControlFocus, Edit1, A
	ControlSetText, Edit1, %strFolder%, A
	ControlSend, Edit1, {Enter}, A
	CheckResult("Explorer_CtrlSendXP", "Is your Explorer folder changed to """ . strFolder . """?")
}
else
	Info("Method 1)`nThis method is reserved for Windows XP users. This test is skipped because you are running on " . A_OSVersion . ".")

; F4 Method
SplitPath, A_AhkPath, , strFolder
Info("Method 2)`nIn the next step, the folder in Explorer should change to your """ . strFolder . """ folder.")
Send, {F4}{Esc}
Sleep, 500 ; long delay for safety
Send, %strFolder%{Enter}
CheckResult("Explorer_F4Esc", "Is your Explorer folder changed to """ . strFolder . """?")

/*
if (A_Language <> "0407")
{
	; Alt-D Method
	strFolder := A_MyDocuments
	Info("Method 3)`nIn the next step, the folder in Explorer should change to your """ . strFolder . """ folder.")
	Send, !d
	Sleep, 500 ; long delay for safety
	Send, %strFolder%{Enter}
	CheckResult("Explorer_AltD", "Is your Explorer folder changed to """ . strFolder . """?")
}
else
	Info("Method 2)`nThis method is skipped for German language.")
*/

; ControlSend Method
strFolder := A_ScriptDir
Info("Method 3`nIn this step, the folder in Explorer should change to your """ . strFolder . """ folder.")
ControlSetText, Edit1, %strFolder%, A
ControlSend, Edit1, {Enter}, A
CheckResult("Explorer_CtrlSend", "Is your Explorer folder changed to """ . strFolder . """?")

; ControlSend Method
strFolder := "C:\Windows"
Info("Method 4)`nIn this last step, the folder in Explorer should change to your """ . strFolder . """ folder.")
Explorer_Navigate(strFolder)
CheckResult("Explorer_Shell", "Is your Explorer folder changed to """ . strFolder . """?")

Send, !{F4}

Info("One last test? We will test if changing folder in Dialog box works well on your system.`n`nThe script will run Notepad and open the ""Open"" dialog box.")
run, Notepad, , , strPID
Sleep, 500 ; long delay for safety
Send, ^o
strFolder := "C:\"
Info("In the next step, the file list in the dialog box should change to your """ . strFolder . """ folder.")
ControlFocus, Edit1, A
ControlGetText, strOldText, Edit1, A
ControlSetText, Edit1, %strFolder%, A
ControlSend, Edit1, {Enter}, A
ControlSetText, Edit1, %strOldText%, A
CheckResult("Notepad_ControlSend", "Is your file list now showing your """ . strFolder . """ folder?")
Info("Thank you. The script will now close Notepad.")
Send, !{F4}
Sleep, 500 ; long delay for safety
WinActivate, ahk_pid %strPID%
Sleep, 500 ; long delay for safety
Send, !{F4}

FileDelete, %strLogFile%
FileAppend, %strLog%, %strLogFile%
Info("Log saved to """ . strLogFile . """. This file will now be opened in Notepad and DELETED from your A_Temp folder.`n`nPlease post the content of this file to the forum thread. Thank you for your help!")
run, Notepad %strLogFile%, , , strPID
WinActivate, ahk_pid %strPID%
sleep, 1000
FileDelete, %strLogFile%
return

; ------------------

ControlEdit1Exist()
{
	ControlGet, strOut, Enabled,, Edit1, A
	return not ErrorLevel
}

Info(str)
{
	MsgBox, 4161, Diag, %str%`n`nPress OK to continue.
	IfMsgBox, Cancel
		ExitApp
}
	
CheckResult(strTestName, strQuestion)
{
	MsgBox, 4131, Diag, %strQuestion%
	IfMsgBox, Cancel
		ExitApp
	IfMsgBox, Yes
		strResult := 1
	IfMsgBox, No
		strResult := 0
	Log(strTestName, strResult)
}

Log(strTestName, strResult)
{
	strLog := strLog . strTestName . " | " . strResult . " | " . strEnv . "`r`n"
}

Explorer_Navigate(FullPath, hwnd="") {  ; by Learning one
    hwnd := (hwnd="") ? WinExist("A") : hwnd ; if omitted, use active window
    WinGet, ProcessName, ProcessName, % "ahk_id " hwnd
    if (ProcessName != "explorer.exe")  ; not Windows explorer
        return
    For pExp in ComObjCreate("Shell.Application").Windows
    {
        if (pExp.hwnd = hwnd) { ; matching window found
            pExp.Navigate("file:///" FullPath)
            return
        }
    }
}
2013-11-05 Edited v2 with fifth method from LearningOne.
2013-11-06 Removed method Alt-D.
Last edited by JnLlnd on 06 Nov 2013, 08:16, edited 2 times in total.
Author of freeware apps Quick Access Popup (http://www.quickaccesspopup.com),
FoldersPopup and CSV Buddy (http://code.jeanlalonde.ca)
User avatar
JnLlnd
Posts: 272
Joined: 29 Sep 2013, 21:29
GitHub: JnLlnd
Location: Montreal, Quebec, Canada
Contact:

Re: 4 options to change the current folder in Windows Explor

04 Nov 2013, 23:58

My results.

On XP:

Code: Select all

Test_Name | Test_Result | A_AhkVersion | A_OSVersion | A_Is64bitOS | A_Language
Explorer_CtrlSendXP | 1 | 1.1.09.02 | WIN_XP | 0 | 040C
Explorer_F4Esc | 1 | 1.1.09.02 | WIN_XP | 0 | 040C
Explorer_AltD | 1 | 1.1.09.02 | WIN_XP | 0 | 040C
Explorer_CtrlSend | 1 | 1.1.09.02 | WIN_XP | 0 | 040C
Notepad_ControlSend | 1 | 1.1.09.02 | WIN_XP | 0 | 040C
On Win7:

Code: Select all

Test_Name | Test_Result | A_AhkVersion | A_OSVersion | A_Is64bitOS | A_Language
Explorer_F4Esc | 1 | 1.1.13.00 | WIN_7 | 1 | 040C
Explorer_AltD | 0 | 1.1.13.00 | WIN_7 | 1 | 040C
Explorer_CtrlSend | 1 | 1.1.13.00 | WIN_7 | 1 | 040C
Notepad_ControlSend | 1 | 1.1.13.00 | WIN_7 | 1 | 040C
Author of freeware apps Quick Access Popup (http://www.quickaccesspopup.com),
FoldersPopup and CSV Buddy (http://code.jeanlalonde.ca)
User avatar
gregster
Posts: 1481
Joined: 30 Sep 2013, 06:48

Re: 4 options to change the current folder in Windows Explor

05 Nov 2013, 00:15

Here you go. But I should say, that I have QTTabBar (http://sourceforge.net/projects/qttabbar/) installed on my system which changes the explorer a bit (multiple tabs etc.). Don't know if it makes a difference in this case...

Code: Select all

Test_Name | Test_Result | A_AhkVersion | A_OSVersion | A_Is64bitOS | A_Language
Explorer_F4Esc | 1 | 1.1.13.01 | WIN_VISTA | 0 | 0407
Explorer_AltD | 0 | 1.1.13.01 | WIN_VISTA | 0 | 0407
Explorer_CtrlSend | 1 | 1.1.13.01 | WIN_VISTA | 0 | 0407
Notepad_ControlSend | 0 | 1.1.13.01 | WIN_VISTA | 0 | 0407
On multiple runs, the last two methods didn't act consistently. Sometimes they work, sometimes not. Only the first one worked every time for me.
User avatar
JnLlnd
Posts: 272
Joined: 29 Sep 2013, 21:29
GitHub: JnLlnd
Location: Montreal, Quebec, Canada
Contact:

Re: 4 options to change the current folder in Windows Explor

05 Nov 2013, 08:25

Thank you gregster. In theory ControlSend would be the best solution but, in real life, I found it less reliable with Explorer. However, I never had problem with ControlSend in standard Dialog boxes as you did (not consistently). I also take note that Alt-D did not work with your German Windows (0407).
Author of freeware apps Quick Access Popup (http://www.quickaccesspopup.com),
FoldersPopup and CSV Buddy (http://code.jeanlalonde.ca)
User avatar
gregster
Posts: 1481
Joined: 30 Sep 2013, 06:48

Re: 4 options to change the current folder in Windows Explor

05 Nov 2013, 09:39

Hi JnLInd,
well, it wasn't really surprising to me that Alt-D didn't work on my german Vista version, because this key combo is reserved in most german language program versions for the main application menu, called 'Datei' (I think, it's called 'File' in english apps). I don't know any replacement for that hotkey, either, on german windows.

But there seems to be some problem with your test script on my windows version, anyway.
The last two methods might be affected by the Alt-D method going rogue. My last run showed:

Code: Select all

Explorer_CtrlSend | 0 | 1.1.13.01 | WIN_VISTA | 0 | 0407
Notepad_ControlSend | 1 | 1.1.13.01 | WIN_VISTA | 0 | 0407

But... in this case the Alt-D method made my Explorer window disappear completely (probably closed, not sure yet, 'Alt-D' and then 'c' would close the explorer on german windows ;) ). So, there was no explorer window anyway, when the Explorer_CtrlSend method was used this time (this happens on most runs). The explorer now came back for the Notepad_ControlSend method.
I will try to take a closer look this evening - I might have to take out the Alt-D method for good results with the last two methods.
Still, there might be an issue with the mentioned explorer extension, but I suspect the Alt-D...
User avatar
Learning one
Posts: 123
Joined: 04 Oct 2013, 13:59
Location: Croatia
Contact:

Re: 4 options to change the current folder in Windows Explor

05 Nov 2013, 11:35

... working on a AHK project where I need to change the current folder in Windows Explorer ...
Try this ;) :

Code: Select all

;=== Hotkeys for testing ===
F1::Explorer_Navigate("C:\")
F2::Explorer_Navigate(A_WinDir)
F3::Explorer_Navigate(A_MyDocuments)

;=== Function ===
Explorer_Navigate(FullPath, hwnd="") {	; by Learning one
	hwnd := (hwnd="") ? WinExist("A") : hwnd ; if omitted, use active window
	WinGet, ProcessName, ProcessName, % "ahk_id " hwnd
	if (ProcessName != "explorer.exe")	; not Windows explorer
		return
	For pExp in ComObjCreate("Shell.Application").Windows
	{
		if (pExp.hwnd = hwnd) {	; matching window found
			pExp.Navigate("file:///" FullPath)
			return
		}
	}
}
User avatar
gregster
Posts: 1481
Joined: 30 Sep 2013, 06:48

Re: 4 options to change the current folder in Windows Explor

05 Nov 2013, 17:09

Ok, the Alt-D part messed up the whole test script on german windows. When commented out, I got

Code: Select all

Explorer_F4Esc | 1 | 1.1.13.01 | WIN_VISTA | 0 | 0407
Explorer_CtrlSend | 1 | 1.1.13.01 | WIN_VISTA | 0 | 0407
Notepad_ControlSend | 1 | 1.1.13.01 | WIN_VISTA | 0 | 0407
on a regular basis. In 5 runs, only the Notepad_ControlSend method failed once, all others times, all three methods worked.

LearningOne's suggestion was also very reliable and fast (on the active window obviously). I was already wondering if you could use a Shell object via COM...
User avatar
JnLlnd
Posts: 272
Joined: 29 Sep 2013, 21:29
GitHub: JnLlnd
Location: Montreal, Quebec, Canada
Contact:

Re: 4 options to change the current folder in Windows Explor

05 Nov 2013, 18:14

@LearningOne: Good stuff. I added this to the test script in the original post if more people want to run it. It worked well on my 2 systems (XP and Win7). Here are my new results.

On XP:

Code: Select all

Test_Name | Test_Result | A_AhkVersion | A_OSVersion | A_Is64bitOS | A_Language
Explorer_CtrlSendXP | 1 | 1.1.09.02 | WIN_XP | 0 | 040C
Explorer_F4Esc | 1 | 1.1.09.02 | WIN_XP | 0 | 040C
Explorer_AltD | 1 | 1.1.09.02 | WIN_XP | 0 | 040C
Explorer_CtrlSend | 1 | 1.1.09.02 | WIN_XP | 0 | 040C
Explorer_Shell | 1 | 1.1.09.02 | WIN_XP | 0 | 040C
Notepad_ControlSend | 1 | 1.1.09.02 | WIN_XP | 0 | 040C
On Win7:

Code: Select all

Test_Name | Test_Result | A_AhkVersion | A_OSVersion | A_Is64bitOS | A_Language
Explorer_F4Esc | 1 | 1.1.13.00 | WIN_7 | 1 | 040C
Explorer_AltD | 0 | 1.1.13.00 | WIN_7 | 1 | 040C
Explorer_CtrlSend | 1 | 1.1.13.00 | WIN_7 | 1 | 040C
Explorer_Shell | 1 | 1.1.13.00 | WIN_7 | 1 | 040C
Notepad_ControlSend | 1 | 1.1.13.00 | WIN_7 | 1 | 040C
@gregster: The Notepad_ControlSend does not work on each run for me too. Also, I removed the Ald-D method froim the script if the user language is German.

@LearningOne: Is the Shell method can be used to change folder inside standard dialog boxes (class #32770) ?
Author of freeware apps Quick Access Popup (http://www.quickaccesspopup.com),
FoldersPopup and CSV Buddy (http://code.jeanlalonde.ca)
User avatar
Learning one
Posts: 123
Joined: 04 Oct 2013, 13:59
Location: Croatia
Contact:

Re: 4 options to change the current folder in Windows Explor

06 Nov 2013, 02:10

Hi JnLlnd,

here are my test results;

Code: Select all

Test_Name | Test_Result | A_AhkVersion | A_OSVersion | A_Is64bitOS | A_Language
Explorer_F4Esc | 1 | 1.1.13.01 | WIN_7 | 1 | 041A
Explorer_AltD | 0 | 1.1.13.01 | WIN_7 | 1 | 041A
Explorer_CtrlSend | 1 | 1.1.13.01 | WIN_7 | 1 | 041A
Explorer_Shell | 1 | 1.1.13.01 | WIN_7 | 1 | 041A
Notepad_ControlSend | 1 | 1.1.13.01 | WIN_7 | 1 | 041A
Alt-D method is a bad choice. For example, in Croatian version of Windows 7, it opens Datoteka menu - translated to english: File menu.
Shell method can't be used to change folder inside standard dialog boxes (class #32770).

FYI, a few years ago, I developed a system which navigates to specified folders in Windows explorer, My Computer, standard dialog boxes (class #32770), and even in some not-standard dialog boxes.

It's called Navigator and it's part of Radial menu v4. By default, it's activated by dragging up with RButton.
If you want, I can extract relevant code from Radial menu which runs Navigator component and post it here.
User avatar
JnLlnd
Posts: 272
Joined: 29 Sep 2013, 21:29
GitHub: JnLlnd
Location: Montreal, Quebec, Canada
Contact:

Re: 4 options to change the current folder in Windows Explor

06 Nov 2013, 08:18

I removed the Alt-D method from the test script.
LearningOne wrote:If you want, I can extract relevant code from Radial menu which runs Navigator component and post it here.
Yes, it would be really appreciated.
Author of freeware apps Quick Access Popup (http://www.quickaccesspopup.com),
FoldersPopup and CSV Buddy (http://code.jeanlalonde.ca)
timeFlies
Posts: 146
Joined: 22 Oct 2013, 20:54
Location: Somewhere in the northern hemisphere.

Re: 4 options to change the current folder in Windows Explor

06 Nov 2013, 16:08

Wow! I haven't had an opportunity to run this, but it looks like LearningOne has a good solution. This was really the only unreliable part in that FavouriteFolders script by rbrtryn.
timeFlies
Posts: 146
Joined: 22 Oct 2013, 20:54
Location: Somewhere in the northern hemisphere.

Re: 4 options to change the current folder in Windows Explor

06 Nov 2013, 16:16

LearningOne wrote:
... working on a AHK project where I need to change the current folder in Windows Explorer ...
Try this ;) :

Code: Select all

;=== Hotkeys for testing ===
F1::Explorer_Navigate("C:\")
F2::Explorer_Navigate(A_WinDir)
F3::Explorer_Navigate(A_MyDocuments)

;=== Function ===
Explorer_Navigate(FullPath, hwnd="") {	; by Learning one
	hwnd := (hwnd="") ? WinExist("A") : hwnd ; if omitted, use active window
	WinGet, ProcessName, ProcessName, % "ahk_id " hwnd
	if (ProcessName != "explorer.exe")	; not Windows explorer
		return
	For pExp in ComObjCreate("Shell.Application").Windows
	{
		if (pExp.hwnd = hwnd) {	; matching window found
			pExp.Navigate("file:///" FullPath)
			return
		}
	}
}
One question: does this method work to navigate to special folders like "My Computer", "Recycle Bin", or "Control Panel"?
User avatar
Learning one
Posts: 123
Joined: 04 Oct 2013, 13:59
Location: Croatia
Contact:

Re: 4 options to change the current folder in Windows Explor

07 Nov 2013, 03:55

@JnLlnd: Ok, I'll do it, probably within next 6 hours... ;)
@chaz: Improved version below supports navigation to special folders. ;) For more info see ShellSpecialFolderConstants enumeration.

Code: Select all

;=== Hotkeys for testing ===
F1::Explorer_Navigate("C:\")
F2::Explorer_Navigate(A_MyDocuments)
F3::Explorer_Navigate(3)		; Control Panel
F4::Explorer_Navigate(17)		; My Computer
F5::Explorer_Navigate(10)		; Recycle Bin

;=== Function ===
Explorer_Navigate(FullPath, hwnd="") {  ; by Learning one. Credits: JnLlnd
	; http://ahkscript.org/boards/viewtopic.php?p=4568#p4568
	; http://ahkscript.org/boards/viewtopic.php?p=4864#p4864
	; http://msdn.microsoft.com/en-us/library/windows/desktop/bb774096%28v=vs.85%29.aspx
	; http://msdn.microsoft.com/en-us/library/aa752094
	hwnd := (hwnd="") ? WinExist("A") : hwnd ; if omitted, use active window
	WinGet, ProcessName, ProcessName, % "ahk_id " hwnd
	if (ProcessName != "explorer.exe")  ; not Windows explorer
		return
	For pExp in ComObjCreate("Shell.Application").Windows
	{
		if (pExp.hwnd = hwnd) { ; matching window found
			if FullPath is integer	; ShellSpecialFolderConstant. Example: "17" (My Computer)
				pExp.Navigate2(FullPath)
			else if (InStr(FullPath, "\\") = 1) ; network path (UNC). Example: "\\my.server.com@SSL\DavWWWRoot\Folder"
				pExp.Navigate(FullPath)
			else
				pExp.Navigate("file:///" FullPath)	; example: "C:\My folder"
			return
		}
	}
}
Last edited by Learning one on 16 Nov 2013, 05:05, edited 1 time in total.
timeFlies
Posts: 146
Joined: 22 Oct 2013, 20:54
Location: Somewhere in the northern hemisphere.

Re: 4 options to change the current folder in Windows Explor

07 Nov 2013, 07:06

My results:

Code: Select all

Test_Name 	       | Test_Result | A_AhkVersion | A_OSVersion | A_Is64bitOS | A_Language
Explorer_F4Esc      | 1           | 1.1.10.01    | WIN_7       | 1           | 0409
Explorer_CtrlSend   | 1           | 1.1.10.01    | WIN_7       | 1           | 0409
Explorer_Shell      | 1           | 1.1.10.01    | WIN_7       | 1           | 0409
Notepad_ControlSend | 1           | 1.1.10.01    | WIN_7       | 1           | 0409
User avatar
Learning one
Posts: 123
Joined: 04 Oct 2013, 13:59
Location: Croatia
Contact:

Re: 4 options to change the current folder in Windows Explor

07 Nov 2013, 09:13

JnLlnd, here's extracted code from Radial menu which runs Navigator. I haven't implemented Explorer_Navigate() function it Navigator codes yet.
User avatar
JnLlnd
Posts: 272
Joined: 29 Sep 2013, 21:29
GitHub: JnLlnd
Location: Montreal, Quebec, Canada
Contact:

Re: 4 options to change the current folder in Windows Explor

07 Nov 2013, 13:34

LearningOne wrote:JnLlnd, here's extracted code from Radial menu which runs Navigator. I haven't implemented Explorer_Navigate() function it Navigator codes yet.
Very interesting. If I understand well, you would replace the part of this code related to Explorer (ExploreWClass,CabinetWClass) with Explorer_Navigate. But the rest is still the best way you found for Dialog boxes. BTW, it looks like you put many hours of trial/error on this! Thanks for sharing :-)
Author of freeware apps Quick Access Popup (http://www.quickaccesspopup.com),
FoldersPopup and CSV Buddy (http://code.jeanlalonde.ca)
User avatar
JnLlnd
Posts: 272
Joined: 29 Sep 2013, 21:29
GitHub: JnLlnd
Location: Montreal, Quebec, Canada
Contact:

Re: 4 options to change the current folder in Windows Explor

07 Nov 2013, 13:43

@LearningOne: have you tested this with Win_8?

If not, it would be nice if a Win_8 user could give a try to your code (replacing line 43 with "if A_OSVersion in WIN_8,WIN_7,WIN_VISTA").
Author of freeware apps Quick Access Popup (http://www.quickaccesspopup.com),
FoldersPopup and CSV Buddy (http://code.jeanlalonde.ca)
User avatar
Learning one
Posts: 123
Joined: 04 Oct 2013, 13:59
Location: Croatia
Contact:

Re: 4 options to change the current folder in Windows Explor

07 Nov 2013, 14:58

If I understand well, you would replace the part of this code related to Explorer (ExploreWClass,CabinetWClass) with Explorer_Navigate
Yes.
looks like you put many hours of trial/error on this! Thanks for sharing
True. Thanks.
have you tested this with Win_8
I don't have opportunity to test anything on Win_8. :(
Do you have opportunity to do tests on Win_8?

* * *

I'm currently upgrading this "Navigator system". It will now use "Explorer_Shell" method and won't depend on "if A_OSVersion in WIN_8,WIN_7,WIN_VISTA".
It will be probably finished tomorrow and I'll post it here for testing... ;)
User avatar
JnLlnd
Posts: 272
Joined: 29 Sep 2013, 21:29
GitHub: JnLlnd
Location: Montreal, Quebec, Canada
Contact:

Re: 4 options to change the current folder in Windows Explor

07 Nov 2013, 15:20

Great! Unfortunately, I can't test on Win_8 myself either... Hopefully, someone else on the forum will be?
Author of freeware apps Quick Access Popup (http://www.quickaccesspopup.com),
FoldersPopup and CSV Buddy (http://code.jeanlalonde.ca)
timeFlies
Posts: 146
Joined: 22 Oct 2013, 20:54
Location: Somewhere in the northern hemisphere.

Re: 4 options to change the current folder in Windows Explor

07 Nov 2013, 20:31

JnLlnd wrote:Great! Unfortunately, I can't test on Win_8 myself either... Hopefully, someone else on the forum will be?
I have Windows 8 installed on my computer alongside Windows 7, but I never use it. I prefer Windows 7, and it's such a pain to close all my programmes and switch OSs. Unfortunately, I have no time to run the test right now since I already expect to be up all night finishing an assignment... ooh, I hate procrastination... my fault. Maybe in a few days.

Return to “Ask For Help”

Who is online

Users browsing this forum: 8bitgunny, afe, grimboto, Hellbent, swagfag, tmplinshi, uberclonescript and 33 guests